# Maintainer: judd <jvinet@zeroflux.org>
# Wersja dla NND: Mis' <michal@doriath.homeip.net>

pkgname=ppp
pkgver=2.4.4
pkgrel=2nnd
pkgdesc="A daemon which implements the PPP protocol for dial-up networking"
url="http://www.samba.org/ppp/"
depends=('glibc' 'libpcap')
makedepends=('libpcap-devel')
backup=('etc/ppp/chap-secrets' 'etc/ppp/pap-secrets' 'etc/ppp/options')
source=(ftp://ftp.samba.org/pub/ppp/ppp-$pkgver.tar.gz \
	http://orakel.tznetz.com/dload/ppp-2.4.4-mppe-mppc-1.1.patch.gz
	options pon poff ppp plog pon.1 ip-up ip-down)
#	http://mppe-mppc.alphacron.de/ppp-2.4.3-mppe-mppc-1.1.patch.gz
md5sums=('183800762e266132218b204dfb428d29' 'ac3233945ebef508b5786435693ae0cf'\
         '7a9259a8f038073eeea7e4552ff1849f' '48c024f73a80c8b69c4def22f86902cc'\
         '2d811f8470ccdea3b8c4505a438483e9' 'c29f21f337381fd67d8eb21b3cefbc2e'\
         '86cdaf133f7a79fb464f02d83afc7734' '44cc662ba9aa61dd9add3ddd4c5ded57'\
         'fbe71936b698233d144d4b8dc31be525' 'f781c8ab9d95f8d9f08d844ee6ba25d3')

build() {
  cd $startdir/src/$pkgname-$pkgver
  patch -p1 < $startdir/src/ppp-2.4.4-mppe-mppc-1.1.patch || return 1

  # fix CFLAGS
  sed -i "s:-O2 -pipe -Wall -g:${CFLAGS}:" pppd/Makefile.linux
  sed -i "s:-g -O2:${CFLAGS}:" pppd/plugins/Makefile.linux
  sed -i "s:-g:${CFLAGS}:" pppd/plugins/pppoe/Makefile.linux
  sed -i "s:-O2:${CFLAGS}:" pppstats/Makefile.linux
  sed -i "s:-O2 -g -pipe:${CFLAGS}:" chat/Makefile.linux
  sed -i "s:-O:${CFLAGS}:" pppdump/Makefile.linux

  # enable active filter
  sed -i "s:^#FILTER=y:FILTER=y:" pppd/Makefile.linux

  ./configure --prefix=/usr --host=i586-pc-linux-gnu || return 1
  make || return 1
  make DESTDIR=$startdir/pkg/usr MANDIR=$startdir/pkg/usr/man/man8 install
  
  install -D -m644 $startdir/src/options $startdir/pkg/etc/ppp/options || return 1
  install -D -m755 $startdir/src/ip-up $startdir/pkg/etc/ppp/ip-up || return 1
  install -D -m755 $startdir/src/ip-down $startdir/pkg/etc/ppp/ip-down || return 1
  install -D -m755 $startdir/src/pon $startdir/pkg/usr/bin/pon || return 1
  install -D -m755 $startdir/src/poff $startdir/pkg/usr/bin/poff || return 1
  install -D -m755 $startdir/src/plog $startdir/pkg/usr/sbin/plog || return 1
  install -D -m600 etc.ppp/pap-secrets $startdir/pkg/etc/ppp/pap-secrets || return 1
  install -D -m600 etc.ppp/chap-secrets $startdir/pkg/etc/ppp/chap-secrets || return 1
  install -D -m755 $startdir/src/ppp $startdir/pkg/etc/rc.d/ppp  || return 1
  install -D -m644 $startdir/src/pon.1 $startdir/pkg/usr/man/man1/pon.1 || return 1
  mkdir -p $startdir/pkg/etc/ppp/peers || return 1
  # Jakiś błąd w Makefilach chyba bo many się rozbiegają gdzie chcą
  rm -rf $startdir/pkg/usr/man/man8/man8
}